田草博客
日志搜索


 标题   内容 评论


网友交流QQ群:11740834 需注明申请加入原因

微信 公众号:ByCAD

邮箱:tiancao1001x126.com
ByCAD,微信公众号
首页 | 普通 | 电脑 | AutoCAD | VB/VB.NET | FLash | 结构 | 建筑 | 电影 | BIM | 规范 | 软件
-电信用户-|-网通用户-
-博客论坛-|-软件下载-
-网站导航-|-规范下载-
-BelovedFLash欣赏-

用户登陆
用户:
密码:
 

站点日历
73 2018 - 12 48
      1
2345678
9101112131415
16171819202122
23242526272829
3031


站点统计

最新评论



Using Curve.Extend How to make the plug-in commands not available
未知 Jig catch user input such as Right Click?   [ 日期:2018-07-12 ]   [ 来自:本站原创 ]  HTML


Imports Autodesk.AutoCAD.ApplicationServices
Imports Autodesk.AutoCAD.DatabaseServices
Imports Autodesk.AutoCAD.EditorInput
Imports Autodesk.AutoCAD.Geometry
Imports Autodesk.AutoCAD.Runtime
Imports System.Runtime.InteropServices
Imports System.Windows.Forms

'////////////////////////////////////////////////////////////////////

'// Use: Jig a newly created block reference

'// Author: Philippe Leefsma, September 2011

'////////////////////////////////////////////////////////////////////

Public Class JigMsgFilter
    Inherits EntityJig
    Private _position As Point3d
    Private _filter As JigFilter
    Public Sub New(ByVal btrId As ObjectId)
        MyBase.New(New BlockReference(Point3d.Origin, btrId))
        _position = Point3d.Origin
        _filter = New JigFilter
        System.Windows.Forms.Application.AddMessageFilter(_filter)
    End Sub
    Public Overloads ReadOnly Property Entity() As BlockReference
        Get
            Return MyBase.Entity
        End Get
    End Property
    Protected Overloads Overrides Function Update() As Boolean
        Entity.Position = _position
        Return True
    End Function
    Protected Overloads Overrides Function Sampler(ByVal prompts As JigPrompts) As SamplerStatus
        Dim jigOpts As JigPromptPointOptions = New JigPromptPointOptions(vbCrLf + "Specify position: ")
        jigOpts.UserInputControls = UserInputControls.NullResponseAccepted
        Dim res As PromptPointResult = prompts.AcquirePoint(jigOpts)
        If (res.Status <> PromptStatus.OK) Then
            Return SamplerStatus.Cancel
        End If
        If (_position = res.Value) Then
            Return SamplerStatus.NoChange
        End If
        _position = res.Value
        Return SamplerStatus.OK
    End Function
    Public Function Run() As PromptStatus
        Dim promptResult As PromptResult = Autodesk.AutoCAD.ApplicationServices.Application.DocumentManager.MdiActiveDocument.Editor.Drag(Me)
        Return promptResult.Status
    End Function

    '////////////////////////////////////////////////////////////

    '// Use: Start Jig command

    '//

    '////////////////////////////////////////////////////////////

    Public Shared Sub JigMsgFilter()
        Dim doc As Document = Autodesk.AutoCAD.ApplicationServices.Application.DocumentManager.MdiActiveDocument()
        Dim db As Database = doc.Database
        Dim ed As Editor = doc.Editor
        Dim res As PromptResult = ed.GetString(vbCrLf + "Enter block name to insert: ")
        If res.Status <> PromptStatus.OK Then
            Exit Sub
        End If
        Using Tx As Transaction = db.TransactionManager.StartTransaction()
            Dim bT As BlockTable = Tx.GetObject(db.BlockTableId, OpenMode.ForRead)
            If (Not bT.Has(res.StringResult)) Then
                ed.WriteMessage(vbCrLf + "Block do not exist :(")
                Exit Sub
            End If
            Dim btrId As ObjectId = bT(res.StringResult)
            Dim jig As New JigMsgFilter(btrId)
            If (jig.Run() <> PromptStatus.OK) Then
                jig.Entity.Dispose()
                Exit Sub
            End If
            Dim model As BlockTableRecord = Tx.GetObject(bT(BlockTableRecord.ModelSpace), OpenMode.ForWrite)
            model.AppendEntity(jig.Entity)
            Tx.AddNewlyCreatedDBObject(jig.Entity, True)
            Tx.Commit()
        End Using
    End Sub
End Class

'////////////////////////////////////////////////////////////

'// Use: Implementation of message filter

'//

'////////////////////////////////////////////////////////////

Public Class JigFilter
    Implements IMessageFilter
    Private WM_RIGHTCLICK As Integer = &H204
    Public Function PreFilterMessage(ByRef m As System.Windows.Forms.Message) As Boolean Implements IMessageFilter.PreFilterMessage
        If m.Msg = WM_RIGHTCLICK Then
            Dim doc As Document = Autodesk.AutoCAD.ApplicationServices.Application.DocumentManager.MdiActiveDocument()
            Dim ed As Editor = doc.Editor()
            ed.WriteMessage(vbCrLf + "Right Button pressed!!")
            'Block message for AutoCAD
            Return True
        End If
        Return False
    End Function
End Class

http://adndevblog.typepad.com/autocad/2012/05/how-to-combine-a-net ... atch-user-input-such-as-right-click.html





引用这个评论 tiancao1001 于 2018-07-12 05:49 PM 发表评论: 
http://adndevblog.typepad.com/autocad/

发表评论 - 不要忘了输入验证码哦!
作者: 用户:  密码:   注册? 验证:  防止恶意留言请输入问题答案:2*5=?  
评论:

禁止表情
禁止UBB
禁止图片
识别链接
识别关键字

字体样式 文字大小 文字颜色
插入粗体文本 插入斜体文本 插入下划线
左对齐 居中对齐 右对齐
插入超级链接 插入邮件地址 插入图像
插入 Flash 插入代码 插入引用
插入列表 插入音频文件 插入视频文件
插入缩进符合
点击下载按钮 下标 上标
水平线 简介分割标记
表  情
 
Tiancao Blog All Rights Reserved 田草博客 版权所有
Copyright ©