' 单行文字文字合并 *************************************************
Sub HBWZ_Text()
    Dim objSelected As Object
    Dim acText  As AcadText
    Dim ssText As AcadSelectionSet
    Dim AllText As String
    Dim H As Double
    Dim W As Double
    Dim S As String
    Dim P As Variant
    On Error Resume Next
    Set ssText = ThisDrawing.SelectionSets.Add("Text")
    '定义过滤机制
    Dim filterType(0) As Integer
    Dim filterData(0) As Variant
    filterType(0) = 0
    filterData(0) = "TEXT"
    
    ssText.SelectOnScreen filterType, filterData
    Dim n As Integer
    Dim i As Integer
    Dim j As Integer
    Dim Temp As Double
    Dim X() As Double
    Dim Index() As Integer
    '对选择的插入点进行排序
    '   只对Y方向进行排序
    '   不对X方向进行排序
    n = ssText.Count - 1
    ReDim X(n)
    ReDim Index(n)
    '           读取Y坐标到数组Y()中
    '           没有排序之前Text在选择集中的序号并没有变化,仍然是0、1、2、3……
    For i = 0 To n
        Set acText = ssText.item(i)
        X(i) = acText.insertionPoint(0)
        Index(i) = i
    Next i
    '           对数组X()排序
    For i = 0 To n - 1
        For j = i + 1 To n
            '如果前一个比后面小的话,则把它的序号和后面的交换。
            If X(i) >= X(j) Then
                '交换X坐标
                Temp = X(i)
                X(i) = X(j)
                X(j) = Temp
                '交换Text在选择集中的位置
                Temp = Index(i)
                Index(i) = Index(j)
                Index(j) = Temp
            End If
        Next j
    Next i
    
    Set acText = ssText.item(Index(0))
    H = acText.height
    W = acText.ScaleFactor
    S = acText.StyleName
    P = acText.insertionPoint
    
    '对选择集中的文字对象进行操作
    For i = 0 To n
            Set acText = ssText.item(Index(i))
            AllText = AllText & acText.textString
            acText.Delete
    Next
    Dim NText As AcadText
    Set NText = ThisDrawing.ModelSpace.AddText(AllText, P, H)
    NText.ScaleFactor = W
    NText.StyleName = S
    ThisDrawing.SelectionSets.item("Text").Delete
    NText.Update
End Sub
'*******************************************************